Fortran: do not evaluate polymorphic functions twice in assignment [PR114012]
Checks
Commit Message
Dear all,
the attached simple patch fixes an issue where we evaluated
polymorphic functions twice in assignments: once for the _data
component, and once for the _vptr. Using save_expr prevents
the double evaluation.
Regtested on x86_64-pc-linux-gnu. OK for mainline?
And a backport to 13-branch after some delay?
Thanks,
Harald
Comments
On 2/25/24 12:26 PM, Harald Anlauf wrote:
> Dear all,
>
> the attached simple patch fixes an issue where we evaluated
> polymorphic functions twice in assignments: once for the _data
> component, and once for the _vptr. Using save_expr prevents
> the double evaluation.
>
> Regtested on x86_64-pc-linux-gnu. OK for mainline?
> And a backport to 13-branch after some delay?
>
> Thanks,
> Harald
>
Yes, simple enough. OK.
Thanks,
Jerry
From 7a16143448ee21b716b54a94f83f9ee477af1b63 Mon Sep 17 00:00:00 2001
From: Harald Anlauf <anlauf@gmx.de>
Date: Sun, 25 Feb 2024 21:18:23 +0100
Subject: [PATCH] Fortran: do not evaluate polymorphic functions twice in
assignment [PR114012]
PR fortran/114012
gcc/fortran/ChangeLog:
* trans-expr.cc (gfc_conv_procedure_call): Evaluate non-trivial
arguments just once before assigning to an unlimited polymorphic
dummy variable.
gcc/testsuite/ChangeLog:
* gfortran.dg/pr114012.f90: New test.
---
gcc/fortran/trans-expr.cc | 4 ++
gcc/testsuite/gfortran.dg/pr114012.f90 | 81 ++++++++++++++++++++++++++
2 files changed, 85 insertions(+)
create mode 100644 gcc/testsuite/gfortran.dg/pr114012.f90
@@ -6691,6 +6691,10 @@ gfc_conv_procedure_call (gfc_se * se, gfc_symbol * sym,
{
tree efield;
+ /* Evaluate arguments just once. */
+ if (e->expr_type != EXPR_VARIABLE)
+ parmse.expr = save_expr (parmse.expr);
+
/* Set the _data field. */
tmp = gfc_class_data_get (var);
efield = fold_convert (TREE_TYPE (tmp),
new file mode 100644
@@ -0,0 +1,81 @@
+! { dg-do run }
+! PR fortran/114012
+!
+! Polymorphic functions were evaluated twice in assignment
+
+program test
+ implicit none
+
+ type :: custom_int
+ integer :: val = 2
+ end type
+
+ interface assignment(=)
+ procedure assign
+ end interface
+ interface operator(-)
+ procedure neg
+ end interface
+
+ type(custom_int) :: i
+ integer :: count_assign, count_neg
+
+ count_assign = 0
+ count_neg = 0
+
+ i = 1
+ if (count_assign /= 1 .or. count_neg /= 0) stop 1
+
+ i = -i
+ if (count_assign /= 2 .or. count_neg /= 1) stop 2
+ if (i% val /= -1) stop 3
+
+ i = neg(i)
+ if (count_assign /= 3 .or. count_neg /= 2) stop 4
+ if (i% val /= 1) stop 5
+
+ i = (neg(i))
+ if (count_assign /= 4 .or. count_neg /= 3) stop 6
+ if (i% val /= -1) stop 7
+
+ i = - neg(i)
+ if (count_assign /= 5 .or. count_neg /= 5) stop 8
+ if (i% val /= -1) stop 9
+
+contains
+
+ subroutine assign (field, val)
+ type(custom_int), intent(out) :: field
+ class(*), intent(in) :: val
+
+ count_assign = count_assign + 1
+
+ select type (val)
+ type is (integer)
+! print *, " in assign(integer)", field%val, val
+ field%val = val
+ type is (custom_int)
+! print *, " in assign(custom)", field%val, val%val
+ field%val = val%val
+ class default
+ error stop
+ end select
+
+ end subroutine assign
+
+ function neg (input_field) result(output_field)
+ type(custom_int), intent(in), target :: input_field
+ class(custom_int), allocatable :: output_field
+ allocate (custom_int :: output_field)
+
+ count_neg = count_neg + 1
+
+ select type (output_field)
+ type is (custom_int)
+! print *, " in neg", output_field%val, input_field%val
+ output_field%val = -input_field%val
+ class default
+ error stop
+ end select
+ end function neg
+end program test
--
2.35.3